函数参考

_WinHttpSimpleSSLRequest

使用SSL请求发送一个简单的表单

#Include <WinHttp.au3>
_WinHttpSimpleSSLRequest($hConnect [, $sType [, $sPath [, $sReferrer = Default [, $sData = Default [, $sHeader = Default [, $fGetHeaders = Default [, $iMode = Default ]]]]]]])

参数

$hConnect _WinHttpConnect 函数返回的句柄
$sType [可选参数] GET 或 POST (默认: GET)
$sPath [可选参数] 请求路径 (默认: "" - 空字符串;表示服务器上的默认页)
$sReferrer [可选参数] 引用页面 (默认: $WINHTTP_NO_REFERER)
$sData [可选参数] POST数据 (默认: $WINHTTP_NO_REQUEST_DATA)
$sHeader [可选参数] 附加头 (默认: $WINHTTP_NO_ADDITIONAL_HEADERS)
$fGetHeaders [可选参数] 返回响应头 (默认: False)
$iMode [可选参数] 读取结果的模式 (默认: 0)
0 - ASCII-文本
1 - UTF-8 文本
2 - 二进制数据

返回值

成功: 如果 $fGetHeaders = False (默认)返回响应数据
[0] 响应头
[1] 响应数据
失败: 返回 0 并设置 @error
1 - 无法打开请求
2 - 无法发送请求
3 - 无法接收响应
4 - $iMode 无效

注意/说明

None.

相关

_WinHttpSimpleRequest, _WinHttpSimpleSendSSLRequest, _WinHttpSimpleSendRequest, _WinHttpQueryHeaders, _WinHttpSimpleReadData

示例/演示


#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6

#include "WinHttp.au3"

Opt("MustDeclareVars", 1)

; !!!注意如果用户名和密码无效, 那么此例子将失败!!!

; 使用真实的数据用来身份验证
Global $sUserName = "SomeUserName"
Global $sPassword = "SomePassword"
Global $sDomain = "www.google.com"
Global $sPage = "accounts/ClientLogin"
; 访问 http://code.google.com/apis/accounts/docs/AuthForInstalledApps.html 获取更多信息
Global $sAdditionalData = "accountType=HOSTED_OR_GOOGLE&Email=" & $sUserName & "&Passwd=" & $sPassword & "&service=mail&source=Gulp-CalGulp-1.05"

; 初始化并获取会话句柄
Global $hOpen = _WinHttpOpen()
; 获取连接句柄
Global $hConnect = _WinHttpConnect($hOpen, $sDomain)

; 进行简单 SSL 请求...
Global $sReturned = _WinHttpSimpleSSLRequest($hConnect, "POST", $sPage, Default, $sAdditionalData)

; 关闭句柄
_WinHttpCloseHandle($hConnect)
_WinHttpCloseHandle($hOpen)

; 看看返回的是什么
MsgBox(0, "Returned", $sReturned)