函数参考

_ClipBoard_Close

关闭剪切板

#Include <Clipboard.au3>
_ClipBoard_Close()

参数

None.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

当窗口完成检查或者修改, 调用这个函数关闭剪切板.
要使其他窗口访问剪贴板. 不要在剪切板放置一个对象后调用这个函数.

相关

_ClipBoard_Open

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI

    ; 创建 GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 打开剪贴板
    If Not _ClipBoard_Open($hGUI) Then _WinAPI_ShowError("_ClipBoard_Open 失败")

    ; 显示可用的剪贴板格式
    MemoWrite("Clipboard formats ..: " & _ClipBoard_CountFormats())

    ; 清空剪贴板
    If Not _ClipBoard_Empty() Then _WinAPI_ShowError("_ClipBoard_Empty failed")

    ; 显示可用的剪贴板格式
    MemoWrite("Clipboard formats ..: " & _ClipBoard_CountFormats())

    ; 关闭剪贴板
    _ClipBoard_Close()

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite