函数参考

_ClipBoard_Empty

清空剪切板并释放剪切板数据句柄.

#Include <Clipboard.au3>
_ClipBoard_Empty()

参数

没有.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 在调用这个函数之前, 您必须使用 _ClipBoard_Open 函数打开剪切板.
 如果你打开剪贴板时指定为 NULL(空)窗口句柄, 此函数成功, 但剪贴板属主也设置为 NULL(空).
 请注意,这将导致(剪贴板设置数据)函数 _ClipBoard_SetData 失败.

相关

_ClipBoard_Open, _ClipBoard_SetData, _ClipBoard_GetOwner, _ClipBoard_SetDataEx

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI

    ; 创建 GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 打开剪贴板
    If _ClipBoard_Open($hGUI) Then
        ShowData($hGUI)

        ; 清空剪贴板
        If Not _ClipBoard_Empty() Then _WinAPI_ShowError("_ClipBoard_Empty failed")

        ; 关闭剪贴板
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open 失败")
    EndIf

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 显示剪贴板统计信息
Func ShowData($hGUI)
    MemoWrite("GUI handle ............: " & $hGUI)
    MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner())
    MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite