函数参考

_ClipBoard_GetSequenceNumber

返回当前窗口状态的剪切板次序

#Include <Clipboard.au3>
_ClipBoard_GetSequenceNumber()

参数

None.

返回值

成功: 返回剪贴板序号
失败: 返回 0

注意/说明

系统为每个窗口位置的剪贴板保持一个序号.
当剪贴板内容发生改变或被清空时序号递增.
你可以跟踪此值,以决定剪贴板内容是否发生了变化和优化创建数据对象.
如果剪贴板被延迟执行, 序号在改变前不会递增, 直到变化出现.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WinAPI.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI

    ; 创建 GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 打开剪贴板
    If _ClipBoard_Open($hGUI) Then

        ShowData($hGUI)

        ; 关闭剪贴板
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open 失败")
    EndIf

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 显示剪贴板统计信息
Func ShowData($hGUI)
    MemoWrite("GUI handle ............: " & $hGUI)
    MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner())
    MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite