函数参考

_ClipBoard_Open

打开剪切板并防止其它程序修改剪切板

#Include <Clipboard.au3>
_ClipBoard_Open($hOwner)

参数

$hOwner 要关联到打开的剪切板的窗口句柄. 如果这个参数为 0, 就打开剪切板
为关联到当前任务.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

如果其他窗口打开了剪切板,这个函数会失败. 调用 _ClipBoard_Close 函数成功后再调用这个函数.
除非调用 _ClipBoard_Empty 函数, 否则 $hOwner 参数指定的窗口不会成为剪切板的所有者.
如果你调用 _ClipBoard_Open 时句柄设置为0, _ClipBoard_Empty就会将剪切板的所有者设置为0,这将导致 _ClipBoard_SetData 失效.

相关

_ClipBoard_Close, _ClipBoard_Empty, _ClipBoard_EnumFormats, _ClipBoard_GetOpenWindow, _ClipBoard_SetDataEx

详情参考

在MSDN中搜索


示例/演示


#include <WindowsConstants.au3>
#include <GUIConstantsEx.au3>
#include <Clipboard.au3>
#include <WinAPI.au3>

Global $iMemo

_Main()

Func _Main()
    Local $hGUI

    ; 创建 GUI
    $hGUI = GUICreate("Clipboard", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 打开剪贴板
    If _ClipBoard_Open($hGUI) Then

        ShowData($hGUI)

    ; 关闭剪贴板
        _ClipBoard_Close()
    Else
        _WinAPI_ShowError("_ClipBoard_Open 失败")
    EndIf

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 显示剪贴板统计信息
Func ShowData($hGUI)
    MemoWrite("GUI handle ............: " & $hGUI)
    MemoWrite("Clipboard owner .......: " & _ClipBoard_GetOwner())
    MemoWrite("Clipboard open window .: " & _ClipBoard_GetOpenWindow())
    MemoWrite("Clipboard sequence ....: " & _ClipBoard_GetSequenceNumber())
    MemoWrite()
EndFunc   ;==>ShowData

; 写入消息到 memo
Func MemoWrite($sMessage = "")
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite