函数参考

_Date_Time_EncodeFileTime

编码并返回一个 $tagFILETIME 数据结构

#Include <Date.au3>
_Date_Time_EncodeFileTime($iMonth, $iDay, $iYear [, $iHour = 0 [, $iMinute = 0 [, $iSecond = 0 [, $iMSeconds = 0]]]])

参数

$iMonth 月
$iDay 日
$iYear 年
$iHour [可选参数] 时
$iMinute [可选参数] 分
$iSecond [可选参数] 秒
$iMSeconds [可选参数] 毫秒

返回值

返回 $tagFILETIME 数据结构

注意/说明

None.

相关

_Date_Time_EncodeSystemTime, $tagFILETIME

示例/演示


#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $tFile

    ; 创建 GUI
    GUICreate("Time", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 对文件时间进行编码
    $tFile = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    MemoWrite("Current date/time .: " & _Date_Time_FileTimeToStr($tFile))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite