函数参考

_Date_Time_GetSystemTimes

返回系统时间信息

#Include <Date.au3>
_Date_Time_GetSystemTimes()

参数

None.

返回值

返回一个下方格式的数组:
    [0] - $tagFILETIME 数据结构,包含总系统空闲时间
    [1] - $tagFILETIME 数据结构,包含总系统核心模式时间
    [2] - $tagFILETIME 数据结构,包含总系统用户模式时间

注意/说明

最低操作系统 - Windows XP/SP1, 2003

相关

$tagFILETIME

示例/演示


#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $aTime

    ; 创建 GUI
    GUICreate("Time", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 获取系统时间
    $aTime = _Date_Time_GetSystemTimes()

    MemoWrite("Idle time ...: " & _Date_Time_FileTimeToStr($aTime[0]))
    MemoWrite("System time .: " & _Date_Time_FileTimeToStr($aTime[1]))
    MemoWrite("User time ...: " & _Date_Time_FileTimeToStr($aTime[2]))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite