函数参考

_Date_Time_LocalFileTimeToFileTime

转换一个本地文件时间到一个文件时间(基于UTC)

#Include <Date.au3>
_Date_Time_LocalFileTimeToFileTime($pLocalTime)

参数

$pLocalTime 要被转化为基于通用时间的文件时间的本地文件时间的$tagFILETIME结构的指针.

返回值

返回转化后的基于文件时间的通用时间的$tagFILETIME结构

注意/说明

该函数使用当前的时区和夏时制设置. 因此, 如果是夏时制, 函数在计算中使用夏时制时间, 即使已将时间转为标准时间.

相关

_Date_Time_FileTimeToLocalFileTime, $tagFILETIME

示例/演示


#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

Global $iMemo

_Main()

Func _Main()
    Local $tTime, $tLocal

    ; 创建 GUI
    GUICreate("Time", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 显示基于协调世界时 (UTC) 的本地日期/时间
    $tTime = _Date_Time_EncodeFileTime(@MON, @MDAY, @YEAR, @HOUR, @MIN, @SEC)
    $tLocal = _Date_Time_LocalFileTimeToFileTime(DllStructGetPtr($tTime))
    MemoWrite("Local date/time .: " & _Date_Time_FileTimeToStr($tLocal))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite