函数参考

_Date_Time_SetTimeZoneInformation

设置当前时区设置

#Include <Date.au3>
_Date_Time_SetTimeZoneInformation($iBias, $sStdName, $tStdDate, $iStdBias, $sDayName, $tDayDate, $iDayBias)

参数

$iBias 计算机上本地时间的当前转换误差. 误差指协调通用(UTC)和本地时间之间的分钟差异. UTC 时间和本地时间的转换公式: UTC = 本地时间 + 误差
$sStdName 标准时间的说明
$tStdDate $tagSYSTEMTIME 结构,包含夏时制标准时过渡到本地的日期时间.
$iStdBias 标准时间与本地时间的偏差值. 在标准时间形成偏差时该值被添加.多数时区中, 该值为0
$sDayName 夏令时的说明
$tDayDate $tagSYSTEMTIME 结构.包含本地标准时间过渡到夏时制的日期时间.
$iDayBias 本地时间转换夏时制时发生的偏差值.在夏时制形成偏差时该值被添加.多数时区中, 该值为 –60.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 要选择正确的月日：
  设置 wYear 项为 0
  wHour 与 wMinute 项代表时间
  wMonth 项代表月份
  wDayOfWeek 项代表星期(周),
  wDay 项代表一月内第几个星期 (取值 1 到 5, 其中 5 表示最后出现的星期).
 举例如下：
 指定 4 月第一个星期日 02:00 的表示法如下:

 wHour = 2, wMonth = 4, wDayOfWeek = 0, wDay = 1.
 指定 10 月最后一个星期四 02:00 的表示法如下:

 wHour = 2, wMonth = 10, wDayOfWeek = 4, wDay = 5.

相关

_Date_Time_GetTimeZoneInformation, $tagSYSTEMTIME

示例/演示


#include <GUIConstantsEx.au3>
#include <Date.au3>
#include <WindowsConstants.au3>

; 由于系统安全性,在 Vista 中 Windows API "SetTimeZoneInformation" 可能被拒绝

Global $iMemo

_Main()

Func _Main()
    Local $aOld, $aNew

    ; 创建 GUI
    GUICreate("Time", 400, 300)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 396, 296, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 显示当前的时区信息
    $aOld = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aOld, "Current")

    ; 设置新的时区信息
    If Not _Date_Time_SetTimeZoneInformation($aOld[1], "A3L CST", $aOld[3], $aOld[4], "A3L CDT", $aOld[6], $aOld[7]) Then
        MsgBox(4096, "错误", "System time zone cannot be SET" & @CRLF & @CRLF & _WinAPI_GetLastErrorMessage())
        Exit
    EndIf

    ; 显示新的时区信息
    $aNew = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aNew, "New")

    ; 重设为原来的时区信息
    _Date_Time_SetTimeZoneInformation($aOld[1], $aOld[2], $aOld[3], $aOld[4], $aOld[5], $aOld[6], $aOld[7])

    ; 显示当前的时区信息
    $aOld = _Date_Time_GetTimeZoneInformation()
    ShowTimeZoneInformation($aOld, "Reset")

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite

; 显示时区信息
Func ShowTimeZoneInformation(ByRef $aInfo, $comment)
    MemoWrite("******************* " & $comment & " *******************")
    MemoWrite("Result ............: " & $aInfo[0])
    MemoWrite("Current bias ......: " & $aInfo[1])
    MemoWrite("Standard name .....: " & $aInfo[2])
    MemoWrite("Standard date/time : " & _Date_Time_SystemTimeToDateTimeStr($aInfo[3]))
    MemoWrite("Standard bias......: " & $aInfo[4])
    MemoWrite("Daylight name .....: " & $aInfo[5])
    MemoWrite("Daylight date/time : " & _Date_Time_SystemTimeToDateTimeStr($aInfo[6]))
    MemoWrite("Daylight bias......: " & $aInfo[7])
EndFunc   ;==>ShowTimeZoneInformation