函数参考

_ExcelReadCell

从一个指定Excel对象的活动工作表读取(单元格)信息.

#Include <Excel.au3>
_ExcelReadCell($oExcel, $sRangeOrRow [, $iColumn = 1])

参数

$oExcel 由预先调用_ExcelBookOpen()或_ExcelBookNew()打开的Excel对象
$sRangeOrRow 要读取的A1范围, 或如果使用R1C1情况下的整数行数
$iColumn [可选参数] 如果使用R1C1方式读取的列(默认为1)

返回值

成功: 返回指定单元格中的数据
失败: 返回 0, 并设置 @error:
@error: 0 - 无错误
1 - 指定的对象不存在
2 - 参数不正确
@extended: 0 - 行超出有效范围
1 - 列超出有效范围

注意/说明

调用函数每次只读取一个单元格
如果指定范围含有多个单元格, 只返回左上角单元格的内容

相关

示例/演示


; ***************************************************************
; 示例 1 - 打开一个工作簿并返回其对象标识符后, 写入内容到单元格.  读取单元格内容, 然后保存并关闭文件.
; *****************************************************************

#include <Excel.au3>

Local $oExcel = _ExcelBookNew() ;创建新工作簿, 并使其可见

_ExcelWriteCell($oExcel, "I Wrote to This Cell", 1, 1) ;写入内容到单元格
Local $sCellValue = _ExcelReadCell($oExcel, 1, 1)
MsgBox(4096, "", "The Cell Value is: " & @CRLF & $sCellValue, 2)

MsgBox(4096, "Exiting", "Press OK to Save File and Exit")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; 现在我们把它保存到临时目录; 必要时覆盖文件
_ExcelBookClose($oExcel) ; 最后我们关闭并退出

; ***************************************************************
; 示例 2 - 打开一个工作簿并返回其对象标识符后, 在循环中写入内容到单元格.  读取单元格内容, 然后保存并关闭文件.
; *****************************************************************

#include <Excel.au3>

$oExcel = _ExcelBookNew() ;创建新工作簿, 并使其可见

For $i = 1 To 5 ;循环
    _ExcelWriteCell($oExcel, $i, $i, 1) ;写入内容到单元格
Next

For $i = 1 To 5 ;循环
    $sCellValue = _ExcelReadCell($oExcel, $i, 1)
    MsgBox(4096, "", "The Cell Value is: " & @CRLF & $sCellValue, 2)
Next

MsgBox(4096, "Exiting", "Press OK to Save File and Exit")
_ExcelBookSaveAs($oExcel, @TempDir & "\Temp.xls", "xls", 0, 1) ; 现在我们把它保存到临时目录; 必要时覆盖文件
_ExcelBookClose($oExcel) ; 最后我们关闭并退出