函数参考

_GDIPlus_ArrowCapSetMiddleInset

获取插入值

#Include <GDIPlus.au3>
_GDIPlus_ArrowCapSetMiddleInset($hArrowCap, $fInset)

参数

$hArrowCap 箭头帽对象句柄
$fInset 返回插入值

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 中间插入值是箭头基线中点向顶点移动的数量单位.
 等于 0 的中间插入值不会产生移动(基线为直线, 箭头帽为正三角形)
 正的(大于0)的插入值使基线中点向顶点方向按指定数量单位移动, 箭头帽形成 ＞ 形
 负的(小于0)的插入值使基线中点按指定数量单位向远离顶点的方向移动, 形成基线中点远离顶点的箭头形状;
 如果负中间插入值的绝对值等于(或大于)箭头线帽的高度, 则箭头线帽为形如 ◆ 的菱形或变异菱形.
 如果中间插入值等于或大于箭头线帽的高度, 则不显示箭头线帽.
 注意:中间插入值只影响填充状态的箭头线帽.

相关

_GDIPlus_ArrowCapGetMiddleInset

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen, $hEndCap, $iInset

    ; 创建 GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; 创建资源
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 4)
    $hEndCap = _GDIPlus_ArrowCapCreate(3, 6)

    ; 描绘箭头 1
    $iInset = 0.5
    _GDIPlus_ArrowCapSetMiddleInset($hEndCap, $iInset)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 120, 390, 120, $hPen)

    ; 描绘箭头 2
    $iInset = _GDIPlus_ArrowCapGetMiddleInset($hEndCap) + 0.5
    _GDIPlus_ArrowCapSetMiddleInset($hEndCap, $iInset)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; 描绘箭头 3
    $iInset = _GDIPlus_ArrowCapGetMiddleInset($hEndCap) + 0.5
    _GDIPlus_ArrowCapSetMiddleInset($hEndCap, $iInset)
    _GDIPlus_PenSetCustomEndCap($hPen, $hEndCap)
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 180, 390, 180, $hPen)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; 清理资源
    _GDIPlus_ArrowCapDispose($hEndCap)
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()
EndFunc   ;==>_Main