函数参考

_GDIPlus_BitmapCreateHBITMAPFromBitmap

从位图对象创建位图句柄

#Include <GDIPlus.au3>
_GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap[, $iARGB = 0xFF000000])

参数

$hBitmap 位图对象句柄
$iARGB [可选参数] 背景色的颜色对象

返回值

成功: 返回 HBITMAP(16位无符号整型位图)句柄
失败: 返回 0

注意/说明

Bitmap对象使用完毕后调用_WinAPI_DeleteObject释放资源

相关

_WinAPI_DeleteObject

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>

_Main()

Func _Main()
    Local $hBMP, $hImage, $iX, $iY, $hClone

    ; 初始化 GDI+ 库
    _GDIPlus_Startup()

    ; 捕获到 32 位位图
    $hBMP = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBMP)

    ; 创建 24 位位图副本
    $iX = _GDIPlus_ImageGetWidth($hImage)
    $iY = _GDIPlus_ImageGetHeight($hImage)
    $hClone = _GDIPlus_BitmapCloneArea($hImage, 0, 0, $iX, $iY, $GDIP_PXF24RGB)

    ; 保存位图到文件
    _GDIPlus_ImageSaveToFile($hClone, @TempDir & "\GDIPlus_Image.bmp")

    ; 清理资源
    _GDIPlus_BitmapDispose($hClone)
    _GDIPlus_BitmapDispose($hImage)
    _WinAPI_DeleteObject($hBMP)

    ; 加载图像
    $hImage = _GDIPlus_ImageLoadFromFile(@TempDir & "\GDIPlus_Image.bmp")
    $hBMP = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hImage)

    ; 保存位图到文件
    _ScreenCapture_SaveImage(@TempDir & "\Image.bmp", $hBMP, True) ; True -> 释放 $hBMP

    ; 清理资源
    _GDIPlus_ImageDispose($hImage)

    ; 关闭 GDI+ 库
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main