函数参考

_GDIPlus_DrawImagePoints

图像绘制到指定的位置.

#Include <GDIPlus.au3>
_GDIPlus_DrawImagePoints($hGraphic, $hImage, $nULX, $nULY, $nURX, $nURY, $nLLX, $nLLY[, $count = 3])

参数

$hGraphic 图形对象的句柄
$hImage 图形对象句柄
$nULX 源图像左上角 X 坐标
$nULY 源图像左上角 Y 坐标
$nURX 源图像右上角 X 坐标
$nURY 源图像右上角 Y 坐标
$nLLX 源图像左下角 X 坐标
$nLLY 源图像左下角 Y 坐标
$count [可选参数] 指定结构内点(x,y)的数量.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 参数 $count 的值必须等于3, 用以指定平行四边形的左上角、右上角和左下角坐标;
 右下角的坐标、及图像的宽度和高度, 由给定的三个坐标计算得出.
 对图像进行缩放以适合平行四边形.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GDIPlus.au3>
#include <ScreenCapture.au3>

_Main()

Func _Main()
    Local $hBitmap1, $hBitmap2, $hImage1, $hImage2, $hGraphic

    ; 初始化 GDI+ 库
    _GDIPlus_Startup()

    ; 捕获整个屏幕
    $hBitmap1 = _ScreenCapture_Capture("")
    $hImage1 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap1)

    ; 捕获屏幕区域
    $hBitmap2 = _ScreenCapture_Capture("", 0, 0, 400, 300)
    $hImage2 = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap2)

    ; 在一幅图像上描绘另一幅图像
    $hGraphic = _GDIPlus_ImageGetGraphicsContext($hImage1)

    _GDIPlus_DrawImagePoints($hGraphic, $hImage2, 100, 100, 600, 170, 130, 570)

    ; 在插入的图像周围描绘边框
    _GDIPlus_GraphicsDrawRect($hGraphic, 100, 100, 400, 300)

    ; 保存由此产生的图像
    _GDIPlus_ImageSaveToFile($hImage1, @MyDocumentsDir & "\GDIPlus_Image.jpg")

    ; 清理资源
    _GDIPlus_ImageDispose($hImage1)
    _GDIPlus_ImageDispose($hImage2)
    _WinAPI_DeleteObject($hBitmap1)
    _WinAPI_DeleteObject($hBitmap2)

    ; 关闭 GDI+ 库
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main