函数参考

_GDIPlus_FontCreate

创建一个字体对象

#Include <GDIPlus.au3>
_GDIPlus_FontCreate($hFamily, $fSize[, $iStyle = 0[, $iUnit = 3]])

参数

$hFamily 字体家族对象句柄
$fSize 字体的大小,测量单位可在下方 $iUnit 参数指定.
$iStyle [可选参数] 字体样式. 可以结合下面的值:
0 - 正常重度或者浓度
1 - 粗体
2 - 斜体
4 - 下划线
8 - 删除线
$iUnit [可选参数] 字体的单位测量方法:
0 - 世界坐标, 非物理单位.
1 - 显示单位
2 - 单位为 1 像素
3 - 单位为 1 点或者 1/72 英寸
4 - 单位为 1 英寸
5 - 单位为 1/300 英寸
6 - 单位为毫米

返回值

成功: 返回字体对象句柄
失败: 返回 0

注意/说明

如果您完成了字体对象, 调用 _GDIPlus_FontDispose 释放资源.

相关

_GDIPlus_FontDispose

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout

    ; 创建 GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; 描绘字符串
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hBrush = _GDIPlus_BrushCreateSolid(0x7F00007F)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFamily, 12, 2)
    $tLayout = _GDIPlus_RectFCreate(140, 110, 100, 20)
    _GDIPlus_GraphicsDrawStringEx($hGraphic, "Hello world", $hFont, $tLayout, $hFormat, $hBrush)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; 清理资源
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main