函数参考

_GDIPlus_ImageGetHeight

获取图像高度

#Include <GDIPlus.au3>
_GDIPlus_ImageGetHeight($hImage)

参数

$hImage 图像对象句柄

返回值

成功: 返回图像像素高度
失败: 返回 -1 并设置@error

注意/说明

None.

相关

_GDIPlus_ImageGetWidth

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>

_Main()

Func _Main()
    Local $hBitmap, $hClone, $hImage, $iX, $iY

    ; 初始化 GDI+ 库
    _GDIPlus_Startup()

    ; 捕获到 32 位位图
    $hBitmap = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; 创建 24 位位图副本
    $iX = _GDIPlus_ImageGetWidth($hImage)
    $iY = _GDIPlus_ImageGetHeight($hImage)
    $hClone = _GDIPlus_BitmapCloneArea($hImage, 0, 0, $iX, $iY, $GDIP_PXF24RGB)

    ; 保存位图到文件
    _GDIPlus_ImageSaveToFile($hClone, @MyDocumentsDir & "\GDIPlus_Image.bmp")

    ; 清理资源
    _GDIPlus_ImageDispose($hClone)
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; 关闭 GDI+ 库
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main