函数参考

_GDIPlus_ImageGetVerticalResolution

获取以图像DPI(每英寸像素)表示的垂直分辨率

#Include <GDIPlus.au3>
_GDIPlus_ImageGetVerticalResolution($hImage)

参数

$hImage 图像对象句柄

返回值

成功: 返回 DPI(每英寸像素) 整数值
失败: 返回 0,设置@error:
@error: 0 - 无错误.
10 - 无效图像句柄

注意/说明

@error 4 依赖于 GDI+ UDF 返回的 -1 或 0, 而不是图像句柄错误.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GDIPlus.au3>
#include <ScreenCapture.au3>
#include <WinAPI.au3>


Global $iMemo

_Main()

Func _Main()
    Local $hBitmap, $hImage

    ; 创建 GUI
    GUICreate("GDI+", 600, 400)
    $iMemo = GUICtrlCreateEdit("", 2, 2, 596, 396, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 初始化 GDI+ 库
    _GDIPlus_Startup()

    ; 捕获到 32 位位图
    $hBitmap = _ScreenCapture_Capture("")
    $hImage = _GDIPlus_BitmapCreateFromHBITMAP($hBitmap)

    ; 显示图像的垂直分辨率, 单位为 DPI (每英寸点数)
    MemoWrite("VerticalResolution DPI : " & _GDIPlus_ImageGetVerticalResolution($hImage));

    ; 清理资源
    _GDIPlus_ImageDispose($hImage)
    _WinAPI_DeleteObject($hBitmap)

    ; 关闭 GDI+ 库
    _GDIPlus_Shutdown()

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage = '')
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite