函数参考

_GDIPlus_PenSetDashStyle

设置画笔短划线样式

#Include <GDIPlus.au3>
_GDIPlus_PenSetDashStyle($hPen[, $iStyle = 0])

参数

$hPen 画笔对象句柄
$iStyle [可选参数] 短画线样式, 可以是下列之一:
$GDIP_DASHSTYLESOLID - 实线.
$GDIP_DASHSTYLEDASH - 虚线.
$GDIP_DASHSTYLEDOT - 点线.
$GDIP_DASHSTYLEDASHDOT - 短线-点交替.
$GDIP_DASHSTYLEDASHDOTDOT - 短线-点-点交替.
$GDIP_DASHSTYLECUSTOM - 用户自定义虚线

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GDIPlus_PenGetDashStyle

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hPen

    ; 创建 GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; 创建资源
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hPen = _GDIPlus_PenCreate(0xFF000000, 8)
    _GDIPlus_PenSetDashStyle($hPen, $GDIP_DASHSTYLEDASHDOT)

    ; 显示笔短划线样式
    MsgBox(4096, "信息", "Pen dash style: " & _GDIPlus_PenGetDashStyle($hPen))

    ; 描绘线条
    _GDIPlus_GraphicsDrawLine($hGraphic, 10, 150, 390, 150, $hPen)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; 清理资源
    _GDIPlus_PenDispose($hPen)
    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main