函数参考

_GDIPlus_StringFormatCreate

创建字符串格式对象

#Include <GDIPlus.au3>
_GDIPlus_StringFormatCreate([$iFormat = 0[, $iLangID = 0]])

参数

$iFormat [可选参数] 格式标志.可以是下列一或多个值:
0x0001 - 阅读顺序从右到左
0x0002 - 文本行垂直绘制
0x0004 - 允许字符串超出所属矩形
0x0020 - 控制字符的 Unicode 布局与典型显示
0x0400 - 指定备用字体,用来替代请求字体不支持的字符
0x0800 - 每行行尾包含的空白符,以字符为测量单位
0x1000 - 禁止该文本换行到下一行
0x2000 - 仅整行都在所属矩形内
0x4000 - 允许显示超出所属矩形的字符和文本
$iLangID [可选参数] 指定使用的语言

返回值

成功: 返回字符串格式对象句柄
失败: 返回 0

注意/说明

 当使完成字符串格式对象, 调用 _GDIPlus_StringFormatDispose 释放资源

相关

_GDIPlus_StringFormatDispose, _GDIPlus_StringFormatSetAlign

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GDIPlus.au3>

_Main()

Func _Main()
    Local $hGUI, $hGraphic, $hBrush, $hFormat, $hFamily, $hFont, $tLayout

    ; 创建 GUI
    $hGUI = GUICreate("GDI+", 400, 300)
    GUISetState()

    ; 描绘字符串
    _GDIPlus_Startup()
    $hGraphic = _GDIPlus_GraphicsCreateFromHWND($hGUI)
    $hBrush = _GDIPlus_BrushCreateSolid(0xFF00007F)
    $hFormat = _GDIPlus_StringFormatCreate()
    $hFamily = _GDIPlus_FontFamilyCreate("Arial")
    $hFont = _GDIPlus_FontCreate($hFamily, 12, 2)
    $tLayout = _GDIPlus_RectFCreate(140, 110, 100, 20)
    _GDIPlus_GraphicsDrawStringEx($hGraphic, "Hello world", $hFont, $tLayout, $hFormat, $hBrush)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    ; 清理资源
    _GDIPlus_FontDispose($hFont)
    _GDIPlus_FontFamilyDispose($hFamily)
    _GDIPlus_StringFormatDispose($hFormat)
    _GDIPlus_BrushDispose($hBrush)

    _GDIPlus_GraphicsDispose($hGraphic)
    _GDIPlus_Shutdown()

EndFunc   ;==>_Main