函数参考

_GUICtrlButton_Click

模拟用户点击按钮

#include <GuiButton.au3>
_GUICtrlButton_Click($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

None.

注意/说明

如果这个按钮在一个对话框里,并且对话框不处于活动状态, _GUICtrlButton_Click 可能会失败.
如果需要提高成功率, 先调用 WinActivate 函数激活对话框后再发送
_GUICtrlButton_Click 到按钮.

相关

详情参考

在MSDN中搜索


示例/演示


#include <GUIConstantsEx.au3>
#include <GuiButton.au3>

Global $btn[6], $iMemo, $iRand

HotKeySet("!b", "Clickit")

_Main()

Func _Main()
    Local $y = 70

    GUICreate("Buttons", 510, 400)
    $iMemo = GUICtrlCreateEdit("", 119, 10, 376, 374, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")

    MemoWrite("Press Alt+b to Click Button")

    $btn[0] = GUICtrlCreateButton("Button1", 10, 10, 100, 50)

    For $x = 1 To 5
        $btn[$x] = GUICtrlCreateButton("Button" & $x + 1, 10, $y, 100, 50)
        $y += 60
    Next

    $iRand = Random(0, 5, 1)
    _GUICtrlButton_SetText($btn[$iRand], "New Text" & $iRand + 1)

    GUISetState()

    While 1
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                ExitLoop
            Case $btn[$iRand]
                MemoWrite(_GUICtrlButton_GetText($btn[$iRand]) & " Clicked")
        EndSwitch
    WEnd

    Exit
EndFunc   ;==>_Main

Func Clickit()
    $iRand = Random(0, 5, 1)
    _GUICtrlButton_Click($btn[$iRand])
EndFunc   ;==>Clickit

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite