函数参考

_GUICtrlComboBox_GetComboBoxInfo

获取关于指定组合框的信息

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetComboBoxInfo($hWnd, ByRef $tInfo)

参数

$hWnd 控件的控件ID/句柄
$tInfo 定义于 $tagCOMBOBOXINFO 的信息

返回值

成功: 返回 True
失败: 返回 False

注意/说明

最低操作系统 - Windows XP.

相关

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $tInfo, $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Get ComboBox Info", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    If _GUICtrlComboBox_GetComboBoxInfo($hCombo, $tInfo) Then
        MemoWrite("Handle to the ComboBox .....: " & DllStructGetData($tInfo, "hCombo"))
        MemoWrite("Handle to the Edit Box .....: " & DllStructGetData($tInfo, "hEdit"))
        MemoWrite("Handle to the drop-down list: " & DllStructGetData($tInfo, "hList"))
    EndIf

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite