函数参考

_GUICtrlComboBox_GetDroppedControlRectEx

获取组合框在打开下拉菜单状态时的屏幕坐标

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetDroppedControlRectEx($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

成功: 返回包含屏幕坐标的 $tagRECT 结构

注意/说明

None.

相关

_GUICtrlComboBox_GetDroppedControlRect, $tagRECT

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $tRect, $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Get Dropped Control RectEx", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Get Dropped Control Rect
    $tRect = _GUICtrlComboBox_GetDroppedControlRectEx($hCombo)

    MemoWrite("X coordinate of the upper left corner ......: " & DllStructGetData($tRect, "Left"))
    MemoWrite("Y coordinate of the upper left corner ......: " & DllStructGetData($tRect, "Top"))
    MemoWrite("X coordinate of the lower right corner .....: " & DllStructGetData($tRect, "Right"))
    MemoWrite("Y coordinate of the lower right corner .....: " & DllStructGetData($tRect, "Bottom"))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite