函数参考

_GUICtrlComboBox_GetEditText

获取组合框编辑控件里的文本

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetEditText($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

成功: 返回编辑框字符串
失败: 返回空字符串

注意/说明

最低操作系统 - Windows XP.
如果消息发送到具有 $CBS_DROPDOWN 或 $CBS_DROPDOWNLIST 样式的组合框, 该函数将失败.

相关

_GUICtrlComboBox_SetEditText, _GUICtrlComboBoxEx_SetEditText

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Get Edit Text", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; 设置编辑框控件显示的文本
    _GUICtrlComboBox_SetEditText($hCombo, StringFormat("%d - Some New Text", Random(1, 20, 1)))

    ; 得到编辑框控件显示的文本
    MemoWrite("Edit Text: " & _GUICtrlComboBox_GetEditText($hCombo))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite