函数参考

_GUICtrlComboBox_GetList

获取来自组合框列表部分的所有项

#include <GuiComboBox.au3>
_GUICtrlComboBox_GetList($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

成功: 返回分隔的全部项目字符串.

注意/说明

默认分隔符为"|",可以使用 opt("GUIDataSeparatorChar","新分隔符") 修改默认分隔符

相关

_GUICtrlComboBox_GetListArray

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $aList, $hCombo
    Opt("GUIDataSeparatorChar", ",") ; set seperator char to char we want to use

    ; 创建 GUI
    GUICreate("ComboBox Get List", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_AddDir($hCombo, "", $DDL_DRIVES, False)

    ; Get List
    $aList = StringSplit(_GUICtrlComboBox_GetList($hCombo), ",")
    For $x = 1 To $aList[0]
        MemoWrite($aList[$x])
    Next

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite