函数参考

_GUICtrlComboBox_ResetContent

移除组合控件编辑框,列表框全部项目

#include <GuiComboBox.au3>
_GUICtrlComboBox_ResetContent($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

None.

注意/说明

None.

相关

_GUICtrlComboBox_DeleteString, _GUICtrlComboBox_AddString

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Reset Content", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296, BitOR($CBS_SIMPLE, $CBS_DISABLENOSCROLL, $WS_VSCROLL))
    GUISetState()

    ; 设置编辑框控件显示的文本
    _GUICtrlComboBox_SetEditText($hCombo, "Edit Text")

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    Sleep(500)

    ; 清空内容
    _GUICtrlComboBox_ResetContent($hCombo)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main