函数参考

_GUICtrlComboBox_SetCueBanner

设置显示在组合框编辑控件中的提示标志

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetCueBanner($hWnd, $sText)

参数

$hWnd 控件的控件ID/句柄
$sText 提示文本字符串

返回值

成功: 返回 True
失败: 返回 False

注意/说明

提示标志是指编辑框中没有选择项时的提示.

最低操作系统: Windows Vista.

相关

_GUICtrlComboBox_GetCueBanner

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo
_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Get Count", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    _GUICtrlComboBox_SetCueBanner($hCombo, "Select an Item")
    $iMemo = GUICtrlCreateEdit("", 10, 50, 376, 234, $WS_VSCROLL)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    MemoWrite("Cue Banner: " & _GUICtrlComboBox_GetCueBanner($hCombo))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite