函数参考

_GUICtrlComboBox_SetExtendedUI

选择默认用户界面或扩展用户界面

#include <GuiComboBox.au3>
_GUICtrlComboBox_SetExtendedUI($hWnd [, $fExtended = False])

参数

$hWnd 控件的控件ID/句柄
$fExtended [可选参数] 指定是否使用扩展组合控件

返回值

成功: 返回 True
失败: 返回 False

注意/说明

默认情况下, F4 键打开或关闭列表框; 键盘上下方向键( ↑ ↓ )改变当前选择.

在组合控件扩展用户界面,F4 键被禁用,按键盘下方向键( ↓ )打开下拉列表;
以后上下方向键( ↑ ↓ )可以改变当前选择

相关

_GUICtrlComboBox_GetExtendedUI

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Set Extended UI", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; Get Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBox_GetExtendedUI($hCombo))

    ; Set Extended UI
    _GUICtrlComboBox_SetExtendedUI($hCombo, True)

    ; Get Extended UI
    MemoWrite("Extended UI: " & _GUICtrlComboBox_GetExtendedUI($hCombo))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite