函数参考

_GUICtrlComboBox_ShowDropDown

显示或隐藏组合列表框的下拉菜单

#include <GuiComboBox.au3>
_GUICtrlComboBox_ShowDropDown($hWnd [, $fShow = False])

参数

$hWnd 控件的控件ID/句柄
$fShow [可选参数] 指定下拉列表框是否显示或隐藏:
 True - 显示列表框
False - 隐藏列表框

返回值

None.

注意/说明

这个函数对具有 $CBS_SIMPLE 样式的组合控件没有任何效果.

相关

_GUICtrlComboBox_GetDroppedState, _GUICtrlComboBoxEx_GetDroppedState

示例/演示


#include <GuiComboBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hCombo

    ; 创建 GUI
    GUICreate("ComboBox Show Drop Down", 400, 296)
    $hCombo = GUICtrlCreateCombo("", 2, 2, 396, 296)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加文件
    _GUICtrlComboBox_BeginUpdate($hCombo)
    _GUICtrlComboBox_AddDir($hCombo, @WindowsDir & "\*.exe")
    _GUICtrlComboBox_EndUpdate($hCombo)

    ; get dropped state
    MemoWrite("Dropped Down State......: " & _GUICtrlComboBox_GetDroppedState($hCombo))

    Sleep(500)

    ; 显示下拉框
    _GUICtrlComboBox_ShowDropDown($hCombo, True)

    Sleep(500)

    ; get dropped state
    MemoWrite("Dropped Down State......: " & _GUICtrlComboBox_GetDroppedState($hCombo))

    Sleep(500)

    ; 隐藏下拉框
    _GUICtrlComboBox_ShowDropDown($hCombo)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite