函数参考

_GUICtrlComboBoxEx_AddString

添加字符串

#Include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_AddString($hWnd, $sText[, $iImage = -1[, $iSelecteImage = -1[, $iOverlayImage = -1[, $iIndent = -1[, $iParam = -1]]]]])

参数

$hWnd 控件句柄
要插入为列表框最后一个项目,则设置 $iIndex 参数为 -1.
$sText 项目文本. 如设置为 -1, 则该值由 $CBEN_GetDISPINFO 通知消息设置.
$iImage [可选参数] 控件项目图标在图像列表中的 0 基索引.
$iSelecteImage [可选参数] 控件项目选中状态时, 图标在图像列表中的 0 基索引.
$iOverlayImage [可选参数] 控件项目覆盖状态时, 图标在图像列表中的 0 基索引.
$iIndent [可选参数] 项目缩进的图像宽度数. 一个缩进量等于一个图像宽度..
$iParam [可选参数] 项目的具体值

返回值

成功: 返回新项目索引
失败: 返回 -1

注意/说明

None.

相关

_GUICtrlComboBoxEx_DeleteString, _GUICtrlComboBoxEx_InitStorage

示例/演示


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hGUI, $hImage, $hCombo


    ; 创建 GUI
    $hGUI = GUICreate("ComboBoxEx Add String", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    For $x = 0 To 146
        _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", $x)
    Next
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    _GUICtrlComboBoxEx_InitStorage($hCombo, 150, 300)

    _GUICtrlComboBoxEx_BeginUpdate($hCombo)
    For $x = 0 To 149
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 200, 1)), $x, $x)
    Next
    _GUICtrlComboBoxEx_EndUpdate($hCombo)

    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main