函数参考

_GUICtrlComboBoxEx_GetCount

获取项目的个数

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_GetCount($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

成功: 返回项目数量
失败: 返回 -1

注意/说明

None.

相关

示例/演示


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hGUI, $hImage, $hCombo

    ; 创建 GUI
    $hGUI = GUICreate("ComboBoxEx Get Count", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 268)
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 5
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x)
    Next

    MsgBox(4160, "信息", "Count: " & _GUICtrlComboBoxEx_GetCount($hCombo))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main