函数参考

_GUICtrlComboBoxEx_SetDroppedWidth

设置组合框的列表框允许的最大像素宽度

#include <GuiComboBoxEx.au3>
_GUICtrlComboBoxEx_SetDroppedWidth($hWnd, $iWidth)

参数

$hWnd 控件句柄
$iWidth 列表框象素宽度

返回值

成功: 返回列表框的新宽度
失败: 返回 -1

注意/说明

默认情况下,下拉列表框最小允许宽度为 0.
下拉列表框的宽度,要么是最低限度的宽度,或是组合控件的宽度,以较大者为佳.

使用 $CBS_DROPDOWN 或 $CBS_DROPDOWNLIST 样式.

相关

_GUICtrlComboBoxEx_GetDroppedWidth

示例/演示


#include <GuiComboBoxEx.au3>
#include <GuiImageList.au3>
#include <GUIConstantsEx.au3>

$Debug_CB = False ;检查传递给 ComboBox/ComboBoxEx 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hImage, $hCombo

    ; 创建 GUI
    $hGUI = GUICreate("ComboBoxEx Set Dropped Width", 400, 300)
    $hCombo = _GUICtrlComboBoxEx_Create($hGUI, "", 2, 2, 394, 100)
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    $hImage = _GUIImageList_Create(16, 16, 5, 3)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 110)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 131)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 165)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 168)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 137)
    _GUIImageList_AddIcon($hImage, @SystemDir & "\shell32.dll", 146)
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlComboBoxEx_CreateSolidBitMap($hCombo, 0x0000FF, 16, 16))
    _GUICtrlComboBoxEx_SetImageList($hCombo, $hImage)

    For $x = 0 To 8
        _GUICtrlComboBoxEx_AddString($hCombo, StringFormat("%03d : Random string", Random(1, 100, 1)), $x, $x)
    Next

    ; 获取下拉框宽度
    MemoWrite("Dropped Width......: " & _GUICtrlComboBoxEx_GetDroppedWidth($hCombo))

    Sleep(500)

    ; 显示下拉框
    _GUICtrlComboBoxEx_ShowDropDown($hCombo, True)

    Sleep(500)

    ; 隐藏下拉框
    _GUICtrlComboBoxEx_ShowDropDown($hCombo)

    ; 设置下拉框宽度
    _GUICtrlComboBoxEx_SetDroppedWidth($hCombo, 500)

    Sleep(500)

    ; 获取下拉框宽度
    MemoWrite("Dropped Width......: " & _GUICtrlComboBoxEx_GetDroppedWidth($hCombo))

    Sleep(500)

    ; 显示下拉框
    _GUICtrlComboBoxEx_ShowDropDown($hCombo, True)

    Sleep(500)

    ; 隐藏下拉框
    _GUICtrlComboBoxEx_ShowDropDown($hCombo)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite