函数参考

_GUICtrlDTP_SetRange

设置系统最小和最大允许时间,使用数据数组.

#Include <GuiDateTimePicker.au3>
_GUICtrlDTP_SetRange($hWnd, ByRef $aRange)

参数

$hWnd 控件句柄
$aRange 如下格式数组:
[ 0] - True 如需设置最小数据; 否则为 False
[ 1] - 最小年份值
[ 2] - 最小月份值
[ 3] - 最小日值
[ 4] - 最小小时值
[ 5] - 最小分钟值
[ 6] - 最小秒值
[ 7] - True 如需设置最大数据; 否则为 False
[ 8] - 最大年份值
[ 9] - 最大月份值
[10] - 最大日值
[11] - 最大小时值
[12] - 最大分钟值
[13] - 最大秒值

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlDTP_GetRange

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiDateTimePicker.au3>

$Debug_DTP = False 检查传递给 DTP 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo, $aRange[14] = [True, @YEAR, 1, 1, 21, 45, 32, True, @YEAR, 12, 31, 23, 59, 59]

_Main()

Func _Main()
    Local $hDTP

    ; 创建 GUI
    GUICreate("DateTimePick Set Range", 400, 300)
    $hDTP = GUICtrlGetHandle(GUICtrlCreateDate("", 2, 6, 190))
    $iMemo = GUICtrlCreateEdit("", 2, 32, 396, 266, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 设置显示的格式
    _GUICtrlDTP_SetFormat($hDTP, "ddd MMM dd, yyyy hh:mm ttt")

    ; 设置日期范围
    _GUICtrlDTP_SetRange($hDTP, $aRange)

    ; 显示日期范围
    $aRange = _GUICtrlDTP_GetRange($hDTP)
    MemoWrite("Minimum date: " & GetDateStr(0))
    MemoWrite("Maximum date: " & GetDateStr(7))
    MemoWrite("Minimum time: " & GetTimeStr(4))
    MemoWrite("Maximum time: " & GetTimeStr(11))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main

; 返回日期部分
Func GetDateStr($iOff = 0)
    Return StringFormat("%02d/%02d/%04d", $aRange[$iOff + 2], $aRange[$iOff + 3], $aRange[$iOff + 1])
EndFunc   ;==>GetDateStr

; 返回时间部分
Func GetTimeStr($iOff = 0)
    Return StringFormat("%02d:%02d:%02d", $aRange[$iOff], $aRange[$iOff + 1], $aRange[$iOff + 2])
EndFunc   ;==>GetTimeStr

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite