函数参考

_GUICtrlEdit_GetRECT

获取一个编辑框控件的格式化矩形

#include <GuiEdit.au3>
_GUICtrlEdit_GetRECT($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

成功: 返回矩形的以下格式数组:
    [0] - 矩形左上角 X 坐标
    [1] - 矩形左上角 Y 坐标
    [2] - 矩形右下角 X 坐标
    [3] - 矩形右下角 Y 坐标

注意/说明

在某种情况下, _GUICtrlEdit_GetRECT 可能不返回准确值.
_GUICtrlEdit_SetRECT 设置的是近似值,但它可以保留少许像素.

相关

_GUICtrlEdit_GetRECTEx

示例/演示


#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; 检查传递给 Edit 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[6] = [50, 130, 210, 290, 378, -1], $aRect

    ; 创建 GUI
    $hGUI = GUICreate("Edit Get RECT", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 5, 97, "shell32.dll")
    _GUICtrlStatusBar_SetText($hStatusBar, "Rect")
    GUISetState()

    ; 获取矩形
    $aRect = _GUICtrlEdit_GetRECT($hEdit)
    $aRect[0] += 10
    $aRect[1] += 10
    $aRect[2] -= 10
    $aRect[3] -= 10

    ; 设置矩形
    _GUICtrlEdit_SetRECT($hEdit, $aRect)

    ; 添加文本
    _GUICtrlEdit_AppendText($hEdit, FileRead($sFile))
    _GUICtrlEdit_LineScroll($hEdit, 0, _GUICtrlEdit_GetLineCount($hEdit) * - 1)

    ; 获取矩形
    $aRect = _GUICtrlEdit_GetRECT($hEdit)
    _GUICtrlStatusBar_SetText($hStatusBar, "Left: " & $aRect[0], 1)
    _GUICtrlStatusBar_SetText($hStatusBar, "Topt: " & $aRect[1], 2)
    _GUICtrlStatusBar_SetText($hStatusBar, "Right: " & $aRect[2], 3)
    _GUICtrlStatusBar_SetText($hStatusBar, "Bottom: " & $aRect[3], 4)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main