函数参考

_GUICtrlEdit_LineScroll

垂直滚动文本

#include <GuiEdit.au3>
_GUICtrlEdit_LineScroll($hWnd, $iHoriz, $iVert)

参数

$hWnd 控件的控件ID/句柄
$iHoriz 指定水平滚动的字符数.
$iVert 指定垂直滚动的行数.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

垂直滚动不超过编辑控件的最后一行.

如果当前行加上 $iVert 参数指定行数超过控件总行数,
该值调整,以便修改最后一行滚动到编辑控件窗口的顶部.

_GUICtrlEdit_LineScroll 将垂直或水平滚动文本.
_GUICtrlEdit_LineScroll 可水平滚动到任何行的最后一个字符.

相关

_GUICtrlEdit_Scroll

示例/演示


#include <GuiEdit.au3>
#include <GuiStatusBar.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_Ed = False ; 检查传递给 Edit 函数的类名, 设置为真并使用另一控件的句柄可以看出它是否有效

_Main()

Func _Main()
    Local $hStatusBar, $hEdit, $hGUI
    Local $sWow64 = ""
    If @AutoItX64 Then $sWow64 = "\Wow6432Node"
    Local $sFile = RegRead("HKEY_LOCAL_MACHINE\SOFTWARE" & $sWow64 & "\AutoIt v3\AutoIt", "InstallDir") & "\include\_ReadMe_.txt"
    Local $aPartRightSide[2] = [378, -1]

    ; 创建 GUI
    $hGUI = GUICreate("Edit Line Scroll", 400, 300)
    $hEdit = GUICtrlCreateEdit("", 2, 2, 394, 268, BitOR($ES_WANTRETURN, $WS_VSCROLL))
    $hStatusBar = _GUICtrlStatusBar_Create($hGUI, $aPartRightSide)
    _GUICtrlStatusBar_SetIcon($hStatusBar, 1, 97, "shell32.dll")
    GUISetState()

    ; 设置边距
    _GUICtrlEdit_SetMargins($hEdit, BitOR($EC_LEFTMARGIN, $EC_RIGHTMARGIN), 10, 10)

    ; 设置文本
    _GUICtrlEdit_SetText($hEdit, FileRead($sFile))

    ; 滚动
    _GUICtrlStatusBar_SetText($hStatusBar, "Scrolled: " & _GUICtrlEdit_LineScroll($hEdit, 0, _GUICtrlEdit_GetLineCount($hEdit)))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main