函数参考

_GUICtrlHeader_GetItem

获取项目信息

#include <GuiHeader.au3>
_GUICtrlHeader_GetItem($hWnd, $iIndex, ByRef $tItem)

参数

$hWnd 控件句柄
$iIndex 项目的 0 基索引
$tItem $tagHDITEM 结构

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 发送消息时, mask 成员表示被请求的信息类型.
 消息返回时,其他成员收到所要求的资料.
 如果 mask 成员指定为零,消息将返回 True,没有任何信息拷贝到数据结构.

相关

_GUICtrlHeader_SetItem, $tagHDITEM

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>
#include <GuiImageList.au3>
#include <WinAPI.au3>

$Debug_HDR = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hHeader, $hImage, $tItem

    ; 创建 GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 创建一个含有图像的图像列表
    $hImage = _GUIImageList_Create(11, 11)
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0xFF0000, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x00FF00, 11, 11))
    _GUIImageList_Add($hImage, _WinAPI_CreateSolidBitmap($hGUI, 0x0000FF, 11, 11))
    _GUICtrlHeader_SetImageList($hHeader, $hImage)

    ; 添加列
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100, 0, 0)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100, 0, 1)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100, 0, 2)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Show column 3 image index
    $tItem = DllStructCreate($tagHDITEM)
    DllStructSetData($tItem, "Mask", $HDI_IMAGE)
    _GUICtrlHeader_GetItem($hHeader, 2, $tItem)
    MemoWrite("Column 3 image index: " & DllStructGetData($tItem, "Image"))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite