函数参考

_GUICtrlHeader_GetItemAlign

获取项目文本对齐方式

#include <GuiHeader.au3>
_GUICtrlHeader_GetItemAlign($hWnd, $iIndex)

参数

$hWnd 控件句柄
$iIndex 项目的 0 基索引

返回值

成功: 返回项目文本对齐方式:
        0 - 左对齐
        1 - 右对齐
        2 - 居中对齐
失败: 返回 -1

注意/说明

None.

相关

_GUICtrlHeader_SetItemAlign

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiHeader.au3>

$Debug_HDR = False ; 检查传递给函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

Global $iMemo

_Main()

Func _Main()
    Local $hGUI, $hHeader

    ; 创建 GUI
    $hGUI = GUICreate("Header", 400, 300)
    $hHeader = _GUICtrlHeader_Create($hGUI)
    $iMemo = GUICtrlCreateEdit("", 2, 24, 396, 274, 0)
    GUICtrlSetFont($iMemo, 9, 400, 0, "Courier New")
    GUISetState()

    ; 添加列
    _GUICtrlHeader_AddItem($hHeader, "Column 1", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 2", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 3", 100)
    _GUICtrlHeader_AddItem($hHeader, "Column 4", 100)

    ; Reset column 1 alignment
    _GUICtrlHeader_SetItemAlign($hHeader, 0, 2)

    ; Show column 1 alignment
    MemoWrite("Column 1 alignment: " & _GUICtrlHeader_GetItemAlign($hHeader, 0))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
EndFunc   ;==>_Main

; 写入一行到 memo 控件
Func MemoWrite($sMessage)
    GUICtrlSetData($iMemo, $sMessage & @CRLF, 1)
EndFunc   ;==>MemoWrite