函数参考

_GUICtrlListBox_Dir

添加目录和文件

#include <GuiListBox.au3>
_GUICtrlListBox_Dir($hWnd, $sFile [, $iAttributes = 0 [, $fBrackets = True]])

参数

$hWnd 控件的控件ID/句柄
$sFile 指定一个绝对路径,相对路径,或文件名
$iAttributes [可选参数] 文件或目录的属性:
$DDL_READWRITE - 可读写文件, 无其他属性
$DDL_READONLY - 只读文件
$DDL_HIDDEN - 隐藏文件
$DDL_SYSTEM - 系统文件
$DDL_DIRECTORY - 包括子目录
$DDL_ARCHIVE - 存档文件
$DDL_DRIVES - 所有映射驱动器
$DDL_EXCLUSIVE - 仅指定属性的文件
$fBrackets [可选参数] 使用 $DDL_DRIVES 参数时是否包含括号

返回值

成功: 返回添加项目的 0 基索引
失败: 返回 -1

注意/说明

如果存储空间不足, 则返回值为 $LB_ERRSPACE

相关

_GUICtrlListBox_InitStorage

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>
#include <Constants.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListBox

    ; 创建 GUI
    GUICreate("List Box Dir", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; 添加文件
    _GUICtrlListBox_BeginUpdate($hListBox)
    _GUICtrlListBox_ResetContent($hListBox)
    _GUICtrlListBox_InitStorage($hListBox, 100, 4096)
    _GUICtrlListBox_Dir($hListBox, @WindowsDir & "\win*.exe")
    _GUICtrlListBox_AddFile($hListBox, @WindowsDir & "\notepad.exe")
    _GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES)
    _GUICtrlListBox_Dir($hListBox, "", $DDL_DRIVES, False)
    _GUICtrlListBox_EndUpdate($hListBox)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main