函数参考

_GUICtrlListBox_GetItemData

获取应用程序定义的与项目关联的值

#include <GuiListBox.au3>
_GUICtrlListBox_GetItemData($hWnd, $iIndex)

参数

$hWnd 控件的控件ID/句柄
$iIndex 项目的 0 基索引

返回值

成功: 返回应用程序定义的值
失败: 返回 -1

注意/说明

None.

相关

_GUICtrlListBox_SetItemData

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

; Warning this should not be used on items created using built-in functions
; Item data is the ControlID for each string

_Main()

Func _Main()
    Local $hListBox

    ; 创建 GUI
    GUICreate("List Box Get Item Data", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; 设置项目数据
    _GUICtrlListBox_SetItemData($hListBox, 4, 1234)

    ; 获取项目数据
    MsgBox(4160, "信息", "Item 5 Data: " & _GUICtrlListBox_GetItemData($hListBox, 4))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main