函数参考

_GUICtrlListBox_GetSelItemsText

获取被选项目的文本

#include <GuiListBox.au3>
_GUICtrlListBox_GetSelItemsText($hWnd)

参数

$hWnd 控件的控件ID/句柄

返回值

成功: 返回下方格式的数组:
    [0] - 数组元素总数
    [1] - 被选项目文本
    [2] - 被选项目文本
    [n] - 被选项目文本

注意/说明

None.

相关

_GUICtrlListBox_GetSelItems

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $sItems, $aItems, $hListBox

    ; 创建 GUI
    GUICreate("List Box Get Sel Items Text", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Select a few items
    _GUICtrlListBox_SetSel($hListBox, 3)
    _GUICtrlListBox_SetSel($hListBox, 4)
    _GUICtrlListBox_SetSel($hListBox, 5)

    ; Get indexes of selected items
    $aItems = _GUICtrlListBox_GetSelItemsText($hListBox)
    For $iI = 1 To $aItems[0]
        $sItems &= @LF & $aItems[$iI]
    Next
    MsgBox(4160, "信息", "Items Selected: " & $sItems)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main