函数参考

_GUICtrlListBox_GetText

返回指定索引的项目(字符串)

#include <GuiListBox.au3>
_GUICtrlListBox_GetText($hWnd, $iIndex)

参数

$hWnd 控件的控件ID/句柄
$iIndex 指定检索字符串的 0 基索引

返回值

成功: 返回项目(字符串)

注意/说明

None.

相关

_GUICtrlListBox_GetTextLen

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListBox

    ; 创建 GUI
    GUICreate("List Box Get Text", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Show item text
    MsgBox(4160, "信息", "Item 5 Text: " & _GUICtrlListBox_GetText($hListBox, 4))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main