函数参考

_GUICtrlListBox_GetTextLen

得到列表框中字符串长度.

#include <GuiListBox.au3>
_GUICtrlListBox_GetTextLen($hWnd, $iIndex)

参数

$hWnd 控件的控件ID/句柄
$iIndex 指定一个基于0开始的项目所在的索引

返回值

成功: 返回字符串长度

注意/说明

None.

相关

_GUICtrlListBox_GetText

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $sText, $hListBox

    ; 创建 GUI
    GUICreate("List Box Get Text Len", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        $sText = StringFormat("%03d : Random string ", Random(1, 100, 1))
        For $iX = 1 To Random(1, 20, 1)
            $sText &= Chr(Random(65, 90, 1))
        Next
        _GUICtrlListBox_AddString($hListBox, $sText)
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Show item text length
    MsgBox(4160, "信息", "Item 5 Text Length: " & _GUICtrlListBox_GetTextLen($hListBox, 4))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main