函数参考

_GUICtrlListBox_InsertString

在列表中插入字符串

#include <GuiListBox.au3>
_GUICtrlListBox_InsertString($hWnd, $sText [, $iIndex = -1])

参数

$hWnd 控件的控件ID/句柄
$sText 要插入的文本字符串
$iIndex [可选参数] 插入位置的 0 基索引.
如果此参数为 -1,则插入到列表的末尾.

返回值

成功: 返回项目位置的 0 基索引
失败: 返回 -1

注意/说明

 如果 $iIndex 为 -1, 则字符串加至列表尾.
 不象 _GUICtrlListBox_AddString 函数,本函数不会导致带有 $LBS_SORT 样式的列表排序

相关

_GUICtrlListBox_AddString, _GUICtrlListBox_DeleteString, _GUICtrlListBox_InitStorage

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListBox

    ; 创建 GUI
    GUICreate("List Box Insert String", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($WS_BORDER, $LBS_NOTIFY, $LBS_DISABLENOSCROLL, $WS_HSCROLL))
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_InsertString($hListBox, "Let's add one really long line of text so that we can set the horizontal scroll bar and " & _
            "show that, unless we dynamically update the scroll bar, it won't show the full line.", 4)
    _GUICtrlListBox_UpdateHScroll($hListBox)
    _GUICtrlListBox_EndUpdate($hListBox)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main