函数参考

_GUICtrlListBox_SelItemRange

在一个多选择列表框中选择一或多个连续的项目

#include <GuiListBox.au3>
_GUICtrlListBox_SelItemRange($hWnd, $iFirst, $iLast [, $fSelect = True])

参数

$hWnd 控件的控件ID/句柄
$iFirst 选择的首项 0 基索引
$iLast 选择的末项 0 基索引
$fSelect [可选参数] 指定如何设置选项. 如果为 True, 字符串被选择且高亮显示;
如果为 False, 去除高亮且不再被选中.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 只能使用于多重选择列表框.
 该函数最多能选择 65,536 个项目范围.

相关

_GUICtrlListBox_SelItemRangeEx

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $sText, $hListBox

    ; 创建 GUI
    GUICreate("List Box Sel Item Range", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL))
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 10
        $sText = StringFormat("%03d : Random string ", Random(1, 100, 1))
        For $iX = 1 To Random(1, 20, 1)
            $sText &= Chr(Random(65, 90, 1))
        Next
        _GUICtrlListBox_AddString($hListBox, $sText)
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; Select a few items
    _GUICtrlListBox_SelItemRange($hListBox, 3, 5)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main