函数参考

_GUICtrlListBox_SetCurSel

选择字符串,如有必要,则滚动到控件可见区.

#include <GuiListBox.au3>
_GUICtrlListBox_SetCurSel($hWnd, $iIndex)

参数

$hWnd 控件的控件ID/句柄
$iIndex 指定被选字符串的 0 基索引.
如果为 -1, 列表框设置为没有选择.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

 该函数只适用于单选列表框.
 你不能用它来建立或删除多重选择列表框中的选择项.

相关

_GUICtrlListBox_GetCurSel

示例/演示


#include <GuiListBox.au3>
#include <GUIConstantsEx.au3>

$Debug_LB = False ;检查传递给 ListBox 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListBox

    ; 创建 GUI
    GUICreate("List Box Set Cur Sel", 400, 296)
    $hListBox = GUICtrlCreateList("", 2, 2, 396, 296)
    GUISetState()

    ; 添加字符串
    _GUICtrlListBox_BeginUpdate($hListBox)
    For $iI = 1 To 9
        _GUICtrlListBox_AddString($hListBox, StringFormat("%03d : Random string", Random(1, 100, 1)))
    Next
    _GUICtrlListBox_EndUpdate($hListBox)

    ; 选择一个项目
    _GUICtrlListBox_SetCurSel($hListBox, 4)

    ; 得到当前所选项目
    MsgBox(4160, "信息", "Current selction: " & _GUICtrlListBox_GetCurSel($hListBox))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main