函数参考

_GUICtrlListView_AddItem

添加项目到列表的末尾

#include <GuiListView.au3>
_GUICtrlListView_AddItem($hWnd, $sText [, $iImage = -1 [, $iParam = 0]])

参数

$hWnd 控件的控件ID/句柄
$sText 项目文本.如果设置为 -1,该项目通过 $LVN_GETDISPINFO 通知消息设置.
$iImage [可选参数] 项目图标在图像列表中的 0 基索引
$iParam [可选参数] 应用程序定义的数据

返回值

成功: 返回新项目的索引
失败: 返回 -1

注意/说明

不能使用这个函数插入子项目. 插入子项目使用 _GUICtrlListView_AddSubItem 函数.

相关

_GUICtrlListView_AddSubItem

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <GuiImageList.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hImage, $hListView

    ; 创建界面
    GUICreate("列表中添加项目", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 加载图像
    $hImage = _GUIImageList_Create()
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0xFF0000, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x00FF00, 16, 16))
    _GUIImageList_Add($hImage, _GUICtrlListView_CreateSolidBitMap($hListView, 0x0000FF, 16, 16))
    _GUICtrlListView_SetImageList($hListView, $hImage, 1)

    ; 添加列
    _GUICtrlListView_InsertColumn($hListView, 0, "Column 1", 100)
    _GUICtrlListView_InsertColumn($hListView, 1, "Column 2", 100)
    _GUICtrlListView_InsertColumn($hListView, 2, "Column 3", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Row 1: Col 1", 0)
    _GUICtrlListView_AddItem($hListView, "Row 2: Col 1", 1)
    _GUICtrlListView_AddItem($hListView, "Row 3: Col 1", 2)


    ; 循环至用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main