函数参考

_GUICtrlListView_Arrange

排列视图项目图标

#include <GuiListView.au3>
_GUICtrlListView_Arrange($hWnd [, $iArrange = 0])

参数

$hWnd 控件的控件ID/句柄
$iArrange [可选参数] 对齐方式. 你可以选择下列值:
0 - 根据控件默认值对齐项目
1 - 沿窗口左对齐项目
2 - 沿窗口上对齐项目
3 - 全部图标对齐网格.

返回值

成功: 返回 True
失败: 返回 False

注意/说明

None.

相关

_GUICtrlListView_SetItemPosition

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Arrange", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_InsertColumn($hListView, 0, "Items", 100)

    ; 添加项目
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 10
        _GUICtrlListView_AddItem($hListView, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Move item 2
    _GUICtrlListView_SetView($hListView, 3)
    _GUICtrlListView_SetItemPosition($hListView, 1, 100, 100)

    MsgBox(4160, "信息", "Arranging items")
    _GUICtrlListView_Arrange($hListView)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main