函数参考

_GUICtrlListView_FindInText

搜索包含指定文本的项目

#Include <GuiListView.au3>
_GUICtrlListView_FindInText($hWnd, $sText[, $iStart = -1[, $fWrapOK = True[, $fReverse = False]]])

参数

$hWnd 控件句柄
$sText 匹配文本
$iStart [可选参数] 搜索开始的 0 基索引,或 -1, 从头开始.
指定索引项自身不包括在搜索范围内.
$fWrapOK [可选参数] 如为 True, 则没有找到匹配项时,从第一项继续搜索
$fReverse [可选参数] 如为 True, 则搜索将从 $iStart - 1 开始到 0. 如果 $fWrapOK = True 搜索将继续

返回值

成功: 返回项目的 0 基索引
失败: 返回 -1

注意/说明

 搜索不区分大小写.
不像 _GUICtrlListView_FindText,这个函数将搜索所有的文字,包括子项.

相关

_GUICtrlListView_FindText

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $iI, $hListView

    GUICreate("ListView Find In Text", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_InsertColumn($hListView, 0, "Items", 100)

    ; 添加项目
    _GUICtrlListView_BeginUpdate($hListView)
    For $iI = 1 To 49
        _GUICtrlListView_AddItem($hListView, "Item " & $iI)
    Next
    _GUICtrlListView_AddItem($hListView, "Target item")
    For $iI = 51 To 100
        _GUICtrlListView_AddItem($hListView, "Item " & $iI)
    Next
    _GUICtrlListView_EndUpdate($hListView)

    ; Search for target item
    $iI = _GUICtrlListView_FindInText($hListView, "tArGeT")
    MsgBox(4160, "信息", "Target Item Index: " & $iI)
    _GUICtrlListView_EnsureVisible($hListView, $iI)

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main