函数参考

_GUICtrlListView_GetColumn

检索列的属性

#Include <GuiListView.au3>
_GUICtrlListView_GetColumn($hWnd, $iIndex)

参数

$hWnd 控件句柄
$iIndex 列的 0 基索引

返回值

返回如下格式数组:
[0] - 列标题和列项目文本对齐方式:
0 - 文本左对齐
1 - 文本右对齐
2 - 居中对齐
[1] - 若为 True, 则项目从图像列表显示图像
[2] - 若为 True, 则位图显示在文本右侧
[3] - 若为 True, 则标题包含图像
[4] - 列像素宽度
[5] - 列标题文本
[6] - 与列关联的子项索引
[7] - 图像在图像列表中的 0 基索引
[8] - 列的 0 基顺序

注意/说明

None.

相关

_GUICtrlListView_SetColumn, _GUICtrlListView_JustifyColumn

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $aInfo, $hListView

    GUICreate("ListView Get Column", 400, 300)
    $hListView = GUICtrlCreateListView("col1|col2|col3", 2, 2, 394, 268)
    _GUICtrlListView_SetExtendedListViewStyle($hListView, BitOR($LVS_EX_FULLROWSELECT, $LVS_EX_CHECKBOXES))
    _GUICtrlListView_SetColumnWidth($hListView, 0, 100)
    GUISetState()

    GUICtrlCreateListViewItem("index 0|data1|more1", $hListView)
    GUICtrlCreateListViewItem("index 1|data2|more2", $hListView)
    GUICtrlCreateListViewItem("index 2|data3|more3", $hListView)
    GUICtrlCreateListViewItem("index 3|data4|more4", $hListView)
    GUICtrlCreateListViewItem("index 4|data5|more5", $hListView)

    ; Change column
    $aInfo = _GUICtrlListView_GetColumn($hListView, 0)
    MsgBox(4160, "信息", "Column 1 Width: " & $aInfo[4])
    _GUICtrlListView_SetColumn($hListView, 0, "New Column 1", 150)
    $aInfo = _GUICtrlListView_GetColumn($hListView, 0)
    MsgBox(4160, "信息", "Column 1 Width: " & $aInfo[4])

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE

    GUIDelete()
EndFunc   ;==>_Main