函数参考

_GUICtrlListView_GetItemRect

检索项目的全部或部分矩形,返回数据数组.

#Include <GuiListView.au3>
_GUICtrlListView_GetItemRect($hWnd, $iIndex[, $iPart = 3])

参数

$hWnd 控件句柄
$iIndex 项目的 0 基索引
$iPart [可选参数] 项目检索部分:
0 - 整个项目的边界矩形
1 - 图标或小图标的边界矩形
2 - 项目文本的边界矩形
3 - 1 和 2 的结合,但不包括报表视图

返回值

返回如下格式数组:
[0] - 矩形左上角 X 坐标
[1] - 矩形左上角 Y 坐标
[2] - 矩形右下角 X 坐标
[3] - 矩形右下角 Y 坐标

注意/说明

None.

相关

_GUICtrlListView_GetItemRectEx

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $aRect, $hListView

    GUICreate("ListView Get Item Rectangle", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Item 1")
    _GUICtrlListView_AddItem($hListView, "Item 2")
    _GUICtrlListView_AddItem($hListView, "Item 3")

    ; Get item 2 rectangle
    $aRect = _GUICtrlListView_GetItemRect($hListView, 1)
    MsgBox(4160, "信息", StringFormat("Item 2 Rectangle : [%d, %d, %d, %d]", $aRect[0], $aRect[1], $aRect[2], $aRect[3]))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main