函数参考

_GUICtrlListView_GetItemRectEx

检索项目的全部或部分矩形,返回数据结构.

#Include <GuiListView.au3>
_GUICtrlListView_GetItemRectEx($hWnd, $iIndex[, $iPart = 3])

参数

$hWnd 控件句柄
$iIndex 项目的 0 基索引
$iPart [可选参数] 项目检索部分:
$LVIR_BOUNDS - 整个项目的边界矩形, 包括图标和标签
$LVIR_ICON - 图标或小图标的边界矩形
$LVIR_LABEL - 项目文本的边界矩形
$LVIR_SELECTBOUNDS - 1 和 2 的结合,但不包括报表视图的列
report view.

返回值

返回 $tagRECT 结构

注意/说明

None.

相关

_GUICtrlListView_GetItemRect, $tagRECT

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>
#include <WindowsConstants.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $tRect, $hListView

    GUICreate("ListView Get Item Rectangle Ex", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Item 1")
    _GUICtrlListView_AddItem($hListView, "Item 2")
    _GUICtrlListView_AddItem($hListView, "Item 3")

    ; Get item 2 rectangle
    $tRect = _GUICtrlListView_GetItemRectEx($hListView, 1)
    MsgBox(4160, "信息", StringFormat("Item 2 Rectangle : [%d, %d, %d, %d]", DllStructGetData($tRect, "Left"), _
            DllStructGetData($tRect, "Top"), DllStructGetData($tRect, "Right"), DllStructGetData($tRect, "Bottom")))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main