函数参考

_GUICtrlListView_GetItemText

取得一个项目或者子项目的文本

#Include <GuiListView.au3>
_GUICtrlListView_GetItemText($hWnd, $iIndex[, $iSubItem = 0])

参数

$hWnd 控件句柄
$iIndex 基于0开始的项目索引
$iSubItem [可选参数] 基于1开始的子项目索引

返回值

返回项目或者子项目文本

注意/说明

要取得一个项目文本, 设置 iSubItem 为 0. 要取得一个子项目文本, 设置 iSubItem 为
基于1开始的子项目索引.

相关

_GUICtrlListView_SetItemText, _GUICtrlListView_GetItemTextArray, _GUICtrlListView_GetItemTextString

示例/演示


#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

$Debug_LV = False ; 检查传递给 ListView 函数的类名, 设置为True并输出到一个控件的句柄,用于检查它是否工作

_Main()

Func _Main()
    Local $hListView

    GUICreate("ListView Get Item Text", 400, 300)
    $hListView = GUICtrlCreateListView("", 2, 2, 394, 268)
    GUISetState()

    ; 添加列
    _GUICtrlListView_AddColumn($hListView, "Items", 100)

    ; 添加项目
    _GUICtrlListView_AddItem($hListView, "Item 1")
    _GUICtrlListView_AddItem($hListView, "Item 2")
    _GUICtrlListView_AddItem($hListView, "Item 3")

    ; Set item 2 text
    _GUICtrlListView_SetItemText($hListView, 1, "New Item 2")
    MsgBox(4160, "信息", "Item 2 Text: " & _GUICtrlListView_GetItemText($hListView, 1))

    ; 循环直到用户退出
    Do
    Until GUIGetMsg() = $GUI_EVENT_CLOSE
    GUIDelete()
EndFunc   ;==>_Main